Jörg Lorenz: Excel, VBA-Beispiele

Excel-Beispiele: Erklärungen, Formeln, VBA-Code und mehr

Hinweise zu den Beispielen finden Sie hier: Beispiele

Kategorie: Beispiel > Excel > VBA > Abfragen

Fehler abfangen und behandeln

Nach oben Adresse des Beitrags Nachricht zum Beitrag an Autor (Tipp 8)

Wie kann ich eine VBA-Fehlermeldung durch eine eigene ersetzen?

Zur weiteren Verarbeitung muss sichergestellt werden, dass wirklich eine Zahl vorliegt. Deshalb wird mittels einer Schleife solange abgefragt, bis wirklich eine Zahl eingegeben wurde:

Sub Fehlermakro()
Dim varI
varI = ""
Do While Not IsNumeric(varI)
    varI = InputBox("Bitte geben Sie eine Zahl ein:", "Zahl eingeben")
Loop
MsgBox varI
End Sub

Oder:

Sub Fehlermakro1()
Dim intI As Integer
On Error GoTo Fehler
'Eingabeaufforderung, da i als Zahl deklariert ist, dürfen auch
'nur solche eingegeben werden. Gibt man einen Text ein, tritt der
'Fehler 13 auf und es wird zur Sprungmarke Fehler gesprungen.
intI = InputBox("Bitte geben Sie eine Zahl ein:", "Zahl eingeben")
'Wird korrekt eine Zahl eingegeben, erscheint die Zahl als Meldung
'und das Makro wird verlassen.
MsgBox intI
Exit Sub
'Fehlerbehandlung:
Fehler:
'Wenn der Fehler 13 aufgetreten ist ...
If Err.Number = 13 Then
    '... eine Meldung bringen ...
    MsgBox "Sie haben keine gültige Zahl eingegeben.", vbOKOnly + vbExclamation, "Fehler!"
'bei einem anderen Fehler eine Meldung bringen
Else
    MsgBox "Ein unerwarteter Fehler ist aufgetreten. Das Makro wird beendet.", vbOKOnly + vbCritical, "Unerwarteter Fehler"
End If
Err.Clear
End Sub

Rückgabewert aus MsgBox

Nach oben Adresse des Beitrags Nachricht zum Beitrag an Autor (Tipp 9)

Wie kann ich abfragen, welche Schaltfläche in einer MsgBox gewählt wurde?

Bemerkungen:

Soll die MsgBox einen Wert zurückgeben, schreibt man die Argumente hinter MsgBox in Klammern, sonst nicht.

Die If-Abfrage ist nur zur besseren Übersichtlichkeit untereinander geschrieben, sie kann auch einfacher geschrieben werden:
If ... Then ... Else

Sub Meldung()
Dim intFrage As Integer
intFrage = MsgBox("Bitte eine Schaltfläche wählen.", vbYesNo + vbExclamation, "Schaltfläche")
If intFrage = vbYes Then
    MsgBox "Sie haben 'Ja' gewählt.", vbOKOnly + vbInformation, "Ja"
Else
    MsgBox "Sie haben 'Nein' gewählt.", vbOKOnly + vbInformation, "Nein"
End If
End Sub

Per Makro Vorlagenverzeichnis abfragen

Nach oben Adresse des Beitrags Nachricht zum Beitrag an Autor (Tipp 10)

Wie kann ich abfragen, in welchem Verzeichnis sich das Vorlagenverzeichnis von Microsoft Office befindet?

Sub VorlagenVerzeichnis()
MsgBox Application.TemplatesPath
End Sub

Abfrage bei Schließen

Nach oben Adresse des Beitrags Nachricht zum Beitrag an Autor (Tipp 11)

Wie kann ich Werte der Excelabfrage beim Schließen der Arbeitsmappe über VBA abfangen, um je nach Entscheidung das Makro zu verzweigen?

In das Modul »DieseArbeitsmappe«:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim strMsg As String
strMsg = "Soll die Arbeitsmappe geschlossen werden?"
Select Case MsgBox(strMsg, vbInformation + vbYesNo)
    Case vbYes: ThisWorkbook.Save
    Case vbNo: Cancel = True
End Select
End Sub

Adresse der aktiven Zelle über VBA-Makro feststellen

Nach oben Adresse des Beitrags Nachricht zum Beitrag an Autor (Tipp 12)

Wie kann ich die Zelladresse bzw. die Zeilen-/Spaltennummer der aktiven Zelle über Makro feststellen lassen?

Hier ein paar Beispiele zur Arbeit mit den Zellangaben:

Sub Zelladresse()
    With ActiveCell
        MsgBox .Address
        MsgBox .Address(False)
        MsgBox .Address(, False)
        MsgBox .Address(False, False)
        MsgBox .Row
        MsgBox .Column
        MsgBox "Zeile: " & .Row & " - Spalte:" & .Column
    End With
End Sub

Wert in erste leere Zelle eintragen

Nach oben Adresse des Beitrags Nachricht zum Beitrag an Autor (Tipp 13)

Wie kann ich einen Zellwert in die erste leere Zelle eines vorgegebenen Bereiches eintragen lassen?

Dim strAddr As String
'Spalte A, entspricht 1:
If IsEmpty(Cells(1, 1)) Then
    strAddr = Cells(1, 1).Address
Else
    strAddr = Cells(Cells(Rows.Count, 1).End(xlUp).Row + 1, 1).Address
End If
Range(strAddr).Value = "Erste leere Zelle"

Abfrage, ob ein Menü in einer Menüleiste vorhanden ist

Nach oben Adresse des Beitrags Nachricht zum Beitrag an Autor (Tipp 14)

Wie kann ich mit VBA abfragen, ob ein bestimmtes Menü in einer bestimmten Menüleiste vorhanden ist?

Zur Arbeit mit Ribbons (dem Menüband, das Symbolleisten und Menüleisten ersetzt hat) empfehle ich die Website von René Holtz:
RibbonX-Workshop

Zur alten Menüleiste:

Sub IstVorhanden()
Dim Ctrl As CommandBarControl
Dim strTxt As String
Dim bolSchalter As Boolean
strTxt = "E&xtras"      'das & steht für die Unterstreichung
For Each Ctrl In Application.CommandBars("Worksheet Menu Bar").Controls
    If Ctrl.Caption = strTxt Then
    bolSchalter = True
    End If
Next Ctrl
If bolSchalter = True Then
    MsgBox "Control gefunden"
Else
    MsgBox "Control nicht gefunden"
End If
End Sub

Excel, Scripte, Alltagslösungen

Jörg Lorenz

Datenschutzerklärung